next | previous | forward | backward | up | top | index | toc | Macaulay2 web site
PrimaryDecomposition > associatedPrimes(Ideal)

associatedPrimes(Ideal) -- find the associated primes of an ideal

Synopsis

Description

ass is an abbreviation for associatedPrimes.

Computes the set of associated primes for the ideal I. 

i1 : R = ZZ/101[a..d];
 
i2 : I = intersect(ideal(a^2,b),ideal(a,b,c^5),ideal(b^4,c^4))

             4     4   2 4
o2 = ideal (b , b*c , a c )

o2 : Ideal of R
 
i3 : associatedPrimes I

o3 = {ideal (b, a), ideal (c, b)}

o3 : List
 
i4 : R = ZZ/7[x,y,z]/(x^2,x*y);
 
i5 : I=ideal(0_R);

o5 : Ideal of R
 
i6 : associatedPrimes I

o6 = {ideal x, ideal (y, x)}

o6 : List

In general, the associated primes are found using Ext modules: the associated primes of codimension i of I and Ext^i(R^1/I,R) are identical, as shown in Eisenbud-Huneke-Vasconcelos, Invent. Math. 110 (1992) 207-235.

primaryDecomposition also computes the associated primes. After doing a primaryDecomposition, calling associatedPrimes requires no new computation, and the list of associated primes is in the same order as the list of primary components returned by primaryDecomposition.

If the ideal is a monomial ideal, then a more efficient method is used. This monomial ideal code was written by Greg Smith and Serkan Hosten. The above comments about primary decomposition hold in this case too. 

i7 : R = QQ[a..f];
 
i8 : I = monomialIdeal ideal"abc,bcd,af3,a2cd,bd3d,adf,f5"

                            2               4            3   5
o8 = monomialIdeal (a*b*c, a c*d, b*c*d, b*d , a*d*f, a*f , f )

o8 : MonomialIdeal of R
 
i9 : ass I

o9 = {monomialIdeal (a, b, f), monomialIdeal (a, d, f), monomialIdeal (b, c, f), monomialIdeal (b, d, f), monomialIdeal (c, d,
     ----------------------------------------------------------------------------------------------------------------------------
     f), monomialIdeal (a, c, d, f)}

o9 : List
 
i10 : primaryDecomposition I

                       2           5                         5                                                  3                
o10 = {monomialIdeal (a , b, a*f, f ), monomialIdeal (a, d, f ), monomialIdeal (b, c, f), monomialIdeal (b, d, f ), monomialIdeal
      ---------------------------------------------------------------------------------------------------------------------------
           4        3                         4   5
      (c, d , d*f, f ), monomialIdeal (a, c, d , f )}

o10 : List
The list of associated primes corresponds to the list of primary components of I: the i-th associated prime is the radical of the i-th primary component.

Original author: C. Yackel, http://faculty.mercer.edu/yackel_ca/.

See also